home *** CD-ROM | disk | FTP | other *** search
/ Language/OS - Multiplatform Resource Library / LANGUAGE OS.iso / dsp / dr.bub / 96000.lha / 96000 / appb / b115b.asm < prev    next >
Assembly Source File  |  1992-04-28  |  8KB  |  213 lines
  1. ; This program was originally published in the Motorola DSP96002 Users Manual
  2. ; and is provided under a DISCLAIMER OF WARRANTY available from Motorola DSP
  3. ; Operation, 6501 William Cannon Drive West, Austin, Texas 78735-8598.  For
  4. ; more information, refer to the DSP96002 Users Manual, Appendix B, DSP
  5. ; Benchmarks.
  6. ;
  7. ; B.1.15.2    Faster Radix 2 Decimation in Time FFT  
  8. ; Complex, Radix 2 Cooley-Tukey Decimation in Time FFT 
  9. ; This program has not been exhaustively tested and may contain errors. 
  10. ; 
  11. ; Faster FFT using Programming Tricks found in Typical FORTRAN Libraries 
  12. ; 
  13. ;      First two passes combined as a four butterfly loop since 
  14. ;            multiplies are trivial. 
  15. ;            2.25 cycles internal (4 cycles external) per Radix 2 
  16. ;            butterfly. 
  17. ;      Middle passes performed with traditional, triple-nested DO loop. 
  18. ;            4 cycles internal (8 cycles external) per Radix 2 butterfly 
  19. ;            plus overhead.  Note that a new pipelining technique is 
  20. ;            being used to minimize overhead. 
  21. ;      Next to last pass performed with double butterfly loop. 
  22. ;            4.5 cycles internal (8.5 cycles external) per Radix 2 
  23. ;            butterfly. 
  24. ;      Last pass has separate single butterfly loop. 
  25. ;            5 cycles internal (9 cycles external) per Radix 2 
  26. ;            butterfly. 
  27. ; 
  28. ;      For 1024 complex points, average Radix 2 butterfly = 3.8 cycles 
  29. ;      internal and 7.35 cycles external, assuming a single external 
  30. ;      data bus. 
  31. ; 
  32. ;      Because of separate passes, minimum of 32 points using these 
  33. ;      optimizations.  Approximately 150 program words required. 
  34. ;      Uses internal X and Y Data ROMs for twiddle factor coefficients 
  35. ;      for any size FFT up to 1024 complex points. 
  36. ; 
  37. ;      Assuming internal program and internal data memory (or two 
  38. ;      external data buses), 1024 point complex FFT is 1.57 msec at 
  39. ;      75 nsec instruction rate.  Assuming internal program and 
  40. ;      external data memory, 1024 point complex FFT is 2.94 msec 
  41. ;      at 75 nsec instruction rate. 
  42. ; 
  43. ; First two passes 
  44. ; 
  45. ;      9 cycles internal, 1.77X faster than 4 cycle Radix 2 bfy 
  46. ;      16 cycles external, 2.0X faster than 4 cycle Radix 2 bfy 
  47. ; 
  48. ;      r0 = a pointer in and out 
  49. ;      r6 = a pointer in 
  50. ;      r4 = b pointer in and out 
  51. ;      r1 = c pointer in and out 
  52. ;      r5 = d pointer in and out 
  53. ;      n5 = 2 
  54. ; 
  55.  
  56.       move      #points,d1.l 
  57.       move      #passes,d9.l 
  58.       move      #data,d0.l 
  59.       move      #coef,m2 
  60.       move      #coefsize,d2.l 
  61.  
  62.       lsr       d1         d0.l,r0 
  63.       lsr       d1         r0,r2 
  64.       add       d1,d0      d1.l,d8.l 
  65.       add       d1,d0      d0.l,r4 
  66.       add       d1,d0      d0.l,r1 
  67.       lsr       d2         d0.l,r5 
  68.       lsr       d2         r0,r6 
  69.       move      #2,n5 
  70.       move      d2.l,n6 
  71.       move      #-1,m0 
  72.       move      m0,m1 
  73.       move      m0,m4 
  74.       move      m0,m5 
  75.       move      m0,m6 
  76.  
  77.       move                              x:(r0),d1.s 
  78.       move                              x:(r1),d0.s 
  79.       move                              x:(r5)-,d2.s 
  80.       move                                           y:(r5)+,d4.s 
  81.       faddsub.s d1,d0                    x:(r4),d5.s 
  82.       faddsub.s d5,d2                                 y:(r4),d7.s 
  83. ; 
  84. ;      Combine first two passes with trivial multiplies. 
  85. ; 
  86.       do      d8.l,_twopass 
  87.  
  88.       faddsub.s  d0,d2                                 y:(r5),d6.s 
  89.       faddsub.s  d7,d6                   d2.s,x:(r0)+  y:(r6)+,d3.s 
  90.       faddsub.s  d1,d7                   d0.s,x:(r4)   y:(r1)+,d2.s 
  91.       faddsub.s  d3,d2                   d1.s,x:(r5)- 
  92.       faddsub.s  d2,d6                   x:(r0)-,d1.s  d4.s,y:(r5)+n5 
  93.       faddsub.s  d3,d5                   x:(r1)-,d0.s  d2.s,y:(r4)+ 
  94.       faddsub.s  d1,d0                   x:(r5),d2.s   d6.s,y:(r0)+ 
  95.       ftfr.s     d5,d4                   x:(r4),d5.s   d3.s,y:(r1) 
  96.       faddsub.s  d5,d2                   d7.s,x:(r1)+  y:(r4),d7.s 
  97. _twopass 
  98.       move                                             d4.s,y:(r5)+ 
  99.  
  100. ; 
  101. ; Middle passes 
  102. ; 
  103.       tfr     d9,d3      #4,d0.l 
  104.       clr     d2         d8.l,d1.l 
  105.       sub     d0,d3      d2.l,m6 
  106.  
  107.       do      d3.l,_end_pass 
  108.       move    d0.l,n2 
  109.       move    r2,r0 
  110.       lsr     d1         m2,r6 
  111.       dec     d1         d1.l,n0 
  112.       dec     d1         d1.l,n1 
  113.       move    d1.l,n3 
  114.       move    n0,n4 
  115.       move    n0,n5 
  116.       lea     (r0)+n0,r1 
  117.       move    r0,r4 
  118.       move    r1,r5 
  119.       move                              x:(r6)+n6,d9.s y:,d8.s 
  120.       move                                             y:(r1),d7.s 
  121.       fmpy.s d8,d7,d3                   x:(r1)+,d6.s 
  122.       fmpy.s d9,d6,d0 
  123.       fmpy.s d9,d7,d1                                  y:(r1),d7.s 
  124.       fmpy   d8,d6,d2  fadd.s    d3,d0  x:(r0),d4.s 
  125.       fmpy   d8,d7,d3  faddsub.s d4,d0  x:(r1)+,d6.s 
  126.  
  127.       do      n2,_end_grp 
  128.  
  129.       do      n3,_end_bfy 
  130.       fmpy  d9,d6,d0   fsub.s    d1,d2  d0.s,x:(r4)    y:(r0)+,d5.s 
  131.       fmpy  d9,d7,d1   faddsub.s d5,d2  d4.s,x:(r5)    y:(r1),d7.s 
  132.       fmpy  d8,d6,d2   fadd      d3,d0  x:(r0),d4.s    d2.s,y:(r5)+ 
  133.       fmpy  d8,d7,d3   faddsub.s d4,d0  x:(r1)+,d6.s   d5.s,y:(r4)+ 
  134. _end_bfy 
  135.       move      (r1)+n1 
  136.       fmpy  d9,d6,d0   fsub.s    d1,d2  d0.s,x:(r4)    y:(r0)+,d5.s 
  137.       fmpy  d9,d7,d1   faddsub.s d5,d2  d4.s,x:(r5)    y:(r1),d7.s 
  138.       fmpy  d8,d6,d2   fadd.s    d3,d0  x:(r0),d4.s    d2.s,y:(r5)+ 
  139.       move                              x:(r6)+n6,d9.s y:,d8.s 
  140.       fmpy  d8,d7,d3   faddsub.s d4,d0  x:(r1)+,d6.s   d5.s,y:(r4)+ 
  141.       fmpy  d9,d6,d0   fsub.s    d1,d2  d0.s,x:(r4)    y:(r0)+n0,d5.s 
  142.       fmpy  d9,d7,d1   faddsub.s d5,d2  d4.s,x:(r5)    y:(r1),d7.s 
  143.       fmpy  d8,d6,d2   fadd.s    d3,d0  x:(r0),d4.s    d2.s,y:(r5)+n5 
  144.       fmpy  d8,d7,d3   faddsub.s d4,d0  x:(r1)+,d6.s   d5.s,y:(r4)+n4 
  145. _end_grp 
  146.       move     n2,d0.l 
  147.       lsl      d0      n0,d1.l 
  148. _end_pass 
  149.  
  150. ; 
  151. ; next to last pass 
  152. ; 
  153.       move      d0.l,n2 
  154.       move      r2,r0 
  155.       move      r0,r4 
  156.       lea      (r0)+2,r1 
  157.       move      r1,r5 
  158.       move      m2,r6 
  159.       move      #3,n0 
  160.       move      n0,n1 
  161.       move      n0,n4 
  162.       move      n0,n5 
  163.       move                              x:(r6)+n6,d9.s  y:,d8.s 
  164.       move                                              y:(r1),d7.s 
  165.       fmpy.s d8,d7,d3                   x:(r1)+,d6.s 
  166.       fmpy.s d9,d6,d0 
  167.       fmpy.s d9,d7,d1                                   y:(r1),d7.s 
  168.       fmpy   d8,d6,d2  fadd.s    d3,d0  x:(r0),d4.s 
  169.       fmpy   d8,d7,d3  faddsub.s d4,d0  x:(r1)+n1,d6.s 
  170.  
  171.       do      n2,_end_next 
  172.       fmpy   d9,d6,d0  fsub.s    d1,d2  d0.s,x:(r4)     y:(r0)+,d5.s 
  173.       fmpy   d9,d7,d1  faddsub.s d5,d2  d4.s,x:(r5)     y:(r1),d7.s 
  174.       fmpy   d8,d6,d2  fadd.s    d3,d0  x:(r0),d4.s     d2.s,y:(r5)+ 
  175.       move                              x:(r6)+n6,d9.s  y:,d8.s 
  176.       fmpy   d8,d7,d3  faddsub.s d4,d0  x:(r1)+,d6.s    d5.s,y:(r4)+ 
  177.       fmpy   d9,d6,d0  fsub.s    d1,d2  d0.s,x:(r4)     y:(r0)+n0,d5.s 
  178.       fmpy   d9,d7,d1  faddsub.s d5,d2  d4.s,x:(r5)     y:(r1),d7.s 
  179.       fmpy   d8,d6,d2  fadd.s    d3,d0  x:(r0),d4.s     d2.s,y:(r5)+n5 
  180.       fmpy   d8,d7,d3  faddsub.s d4,d0  x:(r1)+n1,d6.s  d5.s,y:(r4)+n4 
  181. _end_next 
  182.  
  183. ; 
  184. ; last pass 
  185. ; 
  186.       move      n2,d0.l 
  187.       lsl       d0      r2,r0 
  188.       move      d0.l,n2 
  189.       move      r0,r4 
  190.       lea      (r0)+,r1 
  191.       move      r1,r5 
  192.       move      m2,r6 
  193.       move      #2,n0 
  194.       move      n0,n1 
  195.       move      n0,n4 
  196.       move      n0,n5 
  197.       move                              x:(r6)+n6,d9.s  y:,d8.s 
  198.       move                                              y:(r1),d7.s 
  199.       fmpy.s d8,d7,d3                   x:(r1)+n1,d6.s 
  200.       fmpy.s d9,d6,d0 
  201.       fmpy.s d9,d7,d1                                   y:(r1),d7.s 
  202.       fmpy   d8,d6,d2  fadd.s    d3,d0  x:(r0),d4.s 
  203.       move                              x:(r6)+n6,d9.s  y:,d8.s 
  204.       fmpy   d8,d7,d3  faddsub.s d4,d0  x:(r1)+n1,d6.s 
  205.  
  206.       do      n2,_end_last 
  207.       fmpy   d9,d6,d0  fsub.s    d1,d2  d0.s,x:(r4)     y:(r0)+n0,d5.s 
  208.       fmpy   d9,d7,d1  faddsub.s d5,d2  d4.s,x:(r5)     y:(r1),d7.s 
  209.       fmpy   d8,d6,d2  fadd.s    d3,d0  x:(r0),d4.s     d2.s,y:(r5)+n5 
  210.       move                              x:(r6)+n6,d9.s  y:,d8.s 
  211.       fmpy   d8,d7,d3  faddsub.s d4,d0  x:(r1)+n1,d6.s  d5.s,y:(r4)+n4 
  212. _end_last 
  213.